B I S C U I T's skins

[Biscuit]

Hey everyone !
I'm sharing here reskin i'm working on, as it comes, following inspiration, keeping it fun and creative as much as i can.

>> Biscuit Texture Pack << Here's the download link for the full pack (actually 40mo).

Thanks to everyone sharing informations and explanation about texturing this wonderful game. Thanks to Cashmira and Echelon.
__________________________________________________________________________________________________________

In that package a script is available to help installing texture pack.
Execute script, type the number of the folder you want to install. A backup is made of your existing files beside script in a folder. Each step needs you to confirm to continue. Script is shown below in a spoiler.

You can use this script to install & backup any other files you want to EphineaPSO folder. Just add your files in a subfolder inside "mods". Copy will copy files as they are in your subfolder. For example if you want to copy something in data\scene, then create a subfolder "scene" inside your main one and drop your files in. Start script and select your folder number to backup/install.
_________________________________________________________________________________________________________

Episode 1: FOREST

GreenGrass V1:
Well GreenGrass is my first experience with texturing in PSO so it won't be perfect as some details are really annoying to manage. When i'll be more experienced, maybe i'll give it a refresh.

A cleaner version of forest (maybe too much ) i like.

Spoiler: GREENGRASS Forest Normal to Very Hard | V1

Spoiler: GREENGRASS Forest ULT | V1

FrozenForest:
"Winter is coming" they said. Well Christmas too and you need a frozen forest? There it is.
It's a V1, a simple application of a Gimp filter to my GreenGrass pack. Maybe i'll add a more fancy one later. I understood people like snow forest ^^.

Spoiler: FROZEN Forest Normal to Very Hard | V1

---

Tools and code part :
Sharing some homemade tools here.
I made these tools with caution to avoid any problem on my device and i'm testing it the best i can. I can make some update sometimes. These tools are not dangerous things and i try to be as clear as possible about what they are done for.
If you decide to use it this is your own decision. I can help if you encounter any trouble but i'm not responsible . Anyway creating registry keys and copying files are common things your OS do hundred / thousand times per day and i'm not touching sensible things.

Windows contextual menu entries (registry keys) :
/!\ this modification will apply to all users on device and not only your user. /!\

These are custom Windows contextual menu entries i made to fasten copying files to data / scene. It works with common files used in this folder but not everything (no utility to cover every file extension, to be honest).

So it must work with: .xvm, .afs, .rel, .bml, .prs, .nj, .dat, .gsl, .xj and .bin files.
* You can add or remove files extensions by modifying "AppliesTo" values (see reg code or ask for any question).

How to use:
Right click on the different file types mentioned up there.

How to install:
- Copy/Paste code to a text file, rename extension .reg and then execute file to add keys to your Windows contextual menu.

Spoiler: Create - PSO custom 'Send To' keys

Version 1.0.1 (added separators before and after)

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\*\shell\PSOSendToData]
"Icon"="\"%USERPROFILE%\\EphineaPSO\\psobb.exe\""
"MUIVerb"="PSO: Send to Data"
"AppliesTo"=".xvm OR .afs OR .rel OR .bml OR .prs OR .nj OR .dat OR .gsl OR .xj OR .bin"
"SeparatorBefore"=""

[HKEY_CLASSES_ROOT\*\shell\PSOSendToData\command]
@="cmd.exe /c \"copy \"\"%1\"\" \"\"%%USERPROFILE%%\\EphineaPSO\\data\"\" /V /Y\""

[HKEY_CLASSES_ROOT\*\shell\PSOSendToScene]
"AppliesTo"=".xvm OR .afs OR .rel OR .bml OR .prs OR .nj OR .dat OR .gsl OR .xj OR .bin"
"MUIVerb"="PSO: Send to Scene"
"Icon"="\"%USERPROFILE%\\EphineaPSO\\psobb.exe\""
"SeparatorAfter"=""

[HKEY_CLASSES_ROOT\*\shell\PSOSendToScene\command]
@="cmd.exe /c \"copy \"\"%1\"\" \"\"%%USERPROFILE%%\\EphineaPSO\\data\\scene\"\" /V /Y\""

Spoiler: Delete - PSO custom 'Send To' Keys

Windows Registry Editor Version 5.00

[-HKEY_CLASSES_ROOT\*\shell\PSOSendToData]
[-HKEY_CLASSES_ROOT\*\shell\PSOSendToScene]

Installation & backup script :
This batch script help installing & backing up files to/from EphineaPSO folder. Any files if you respect EphineaPSO folder structure inside the folder you add.
Create a folder "mods" beside the script and add your fils in subfolder.

Spoiler: Mods install & backup script

REM Script Author: DeadMeat / B I S C U I T / Discord : biscuitisnotmyname

@echo off
cls
setlocal EnableDelayedExpansion

REM SETTING INSTALLATION FOLDER HERE
set "dest=%USERPROFILE%\EphineaPSO\data"

REM Setting mods folder
set "mods_base=%~dp0mods"

cls
echo                     .:.:.:.:.:.:.:.:.:.:.:.:.:.:.
echo                     .: Biscuit's mod installer :.
echo                     .:.:.:.:.:.:.:.:.:.:.:.:.:.:.
echo.
echo This installer is designed to help with backuping and copying files to "USERNAME\EphineaPSO\data" folder.
echo.
echo Quick instructions:
echo.
echo Files must be added in "mods" folder inside subfolders named like : "name_without_space".
echo Files inside your folder must follow the common structure of "EphineaPSO" folder : "data\scene".
echo.
echo Enjoy and let me know about any advice or improvement :-)
echo.
pause

:MAIN_MENU

for /f "tokens=1-7 delims=/:., " %%a in ("%date% %time%") do (
    set "datetime=%%c%%a%%b_%%d%%e%%f"
)
set "datetime=%datetime: =0%"

REM Setting backup folder (default is beside script)
set "current_backup_folder=%~dp0%datetime%_BACKUP"

cls
echo.
echo Current values set in script:
echo.
echo .:. Destination Folder:
echo    "%dest%"
echo.
echo IF THE GAME IS NOT INSTALLED IN THE DEFAULT PATH, PLEASE MODIFY THE "DEST" VARIABLE IN THE SCRIPT BEFORE CONTINUE.
echo.
echo .:. Backup folder:
echo    "%current_backup_folder%"
echo.
echo .:. Mods main folder (drop any PSO mod INSIDE_A_SUBFOLDER here):
echo    "%mods_base%"
echo.
echo -----------------------------------------------------
echo.
if not exist "%dest%" (
    echo The folder EphineaPSO does not exist at: %dest%.
    echo.
    pause
    goto :MAIN_MENU
)

if not exist "%mods_base%" (
    echo The source files folder %mods_base% does not exist.
    echo.
    pause
    goto :MAIN_MENU
)

echo Subfolders detected in "mods" :
echo ----------------------------------------
set /a count=0
for /d %%d in ("%mods_base%\*") do (
    set /a count+=1
    echo [!count!] %%~nxd
    set "mod_choice[!count!]=%%d"
)
echo ----------------------------------------
echo.

if %count% equ 0 (
    echo No mod folders found in "%mods_base%".
    echo Ensure your mods are inside subfolders.
    echo.
    pause
    goto :MAIN_MENU
)

:GET_CHOICE
set "user_choice="
set /p "user_choice=Enter the number of the folder to install: "
if not defined user_choice goto GET_CHOICE
if !user_choice! LSS 1 goto GET_CHOICE
if !user_choice! GTR !count! goto GET_CHOICE

set "selected_mod_folder=!mod_choice[%user_choice%]!"

for %%A in ("!selected_mod_folder!") do set "display_folder_name=%%~nxA"
echo.
echo You have chosen to install folder:
echo.
echo "%display_folder_name%"
echo.
echo Press any key to continue or close script to start again
echo.
pause
cls

echo.
echo Step 1: Backing up existing files (if present) to "%current_backup_folder%" ...
if not exist "%current_backup_folder%" (
    mkdir "%current_backup_folder%"
)

for /f "delims=" %%f in ('dir /b /s /a-d "%selected_mod_folder%"') do (
 
    set "full_mod_file_path=%%f"
    set "relative_file_path=!full_mod_file_path:%selected_mod_folder%\=!"
    set "game_dest_file_path=%dest%\!relative_file_path!"
    set "backup_target_file_path=%current_backup_folder%\!relative_file_path!"
 
    for %%g in ("!backup_target_file_path!") do set "backup_target_dir=%%~dpg"

    if exist "!game_dest_file_path!" (
        echo Backing up "!game_dest_file_path!" ...
        if not exist "!backup_target_dir!" (
            mkdir "!backup_target_dir!"
        )
        copy /y "!game_dest_file_path!" "!backup_target_file_path!" >nul
    ) else (
        echo NO BACKUP DONE for : "!relative_file_path!".  File not found at destination.
    )
)

echo Step 1: Backup completed.
echo.
echo Going for "Step 2: Installation"
echo.
pause

echo Step 2: Installing new mod to "%dest%" ...
echo.
xcopy "%selected_mod_folder%" "%dest%" /E /H /Y /K /R
echo.
echo Step 2: Installation of "%display_folder_name%" completed.
echo.
echo Going back to main menu ...
echo.
pause
goto :MAIN_MENU

endlocal
exit /b 0

 

[Biscuit]

I still have some trouble with the doors and some plants in forest, staying in original colors that i cant modify. If anyone is passing here and have a clue on how to edit, i'll take !

 

[Biscuit]

Hey, new maps forest02 (N-VH) and aforest01/02 (ULT) added. A basic version of Frozen forest 02 (N-VH) is now available too. Take care <3

 

[Biscuit]

Hey there.
Quick update of Ult GreenGrass Forest 1 with mipmaps (no more moire effect).

Take care

 

[Biscuit]

corrected forest 1 bush, which is still not perfect but that's it for now ^^

 

[Biscuit]

Hey there.
I just updated the installation script to manage the EphineaPSO common folder structure.
So now the script can install and backup any file you want to send to data or data\scene.


Place your files in "mods" in a subfolder named like "my_subfolder_without_space".

Inside your subfloder, you must follow the common sctructure seen in EphineaPSO like this :

.:.
my_subfolder_name_without_space >
files_located_in_data
scene >
files_located_in_scene
.:.

I hope this is clear enought .

This is very simple to use. I hope you'll enjoy this.

Take care everyone <3

 

[Biscuit]

Another update today to share windows contextual menu options i made because i don't like to work in data\scene directly.

These entries allow to send files directly to "EphineaPSO\data" or "EphineaPSO\data\scene" by right-clicking.

The "AppliesTo" value specifiy which file extensions it will work with. I've added more than i use to help you all but only a few number is really necessary tbh.

To avoid any security subject, code is visible, you can see it, copy/paste by yourself to a text file, rename extension to ".reg" and execute. Or add things by hand if you're aware about registry.

[Code in first post]

Take Care <3