Biscuit
creative weird ADHD
- Gender
- Male
- Guildcard
- 42023013
As texturing beginner, I'm sharing here reskin i'm working on.
>> Biscuit Texture Pack << Here's the download link for the full pack (actually 40mo).
Thanks to everyone sharing informations and explanation about texturing this wonderful game.
Thanks to Cashmira and Echelon for inspiring me to take on these projects and continue working on them. I would be honored to collaborate on projects one day.
__________________________________________________________________________________________________________
In that package a script is available to help installing texture pack.
Execute script, type the number of the folder you want to install. A backup is made of your existing files beside script in a folder. Each step needs you to confirm to continue. Script is shown below in a spoiler.
You can use this script to install & backup any other files you want to EphineaPSO folder. Just add your files in a subfolder inside "mods". Copy will copy files as they are in your subfolder. For example if you want to copy something in data\scene, then create a subfolder "scene" inside your main one and drop your files in. Start script and select your folder number to backup/install.
_________________________________________________________________________________________________________
Episode 1: FOREST
GreenGrass :
Episode 1: FOREST
GreenGrass :
Well GreenGrass is my first experience with texturing in PSO (and any game). It was a nice experience for a first shot.
It's a cleaner version of forest i like. Some textures could have a little more natural curves, but I'll stop with this theme for now.
When you first land on this page, you might think it's just a skin, but texturing is a lot of work. Finding the right texture, matching it, linking it, and managing some textures that share two in one (ground + grass, sand + grass, river + grass, etc.) was a daunting task.
I started with the Normal to Very Hard version but I think it's better to start with the Ultimate version because there are more textures in it. When you're done, you can paste to the NVH xvm file.
Please enjoy
.
FrozenForest :
This is a test!
A simple test with an artistic filter applied to GreenGrass in Gimp. But it really does render a frozen theme! I know people like the frozen theme in PSO, and I'll work on it soon to come up with something prettier, I promise
.Especially applying the mipmaps I forgot about, which give a rather ugly line effect in the distance.
For now, I have a lot of other ideas in mind for other maps, and I need to move forward and mix things up.
Please enjoy !
Tools & Code
I love automating redundant tasks, if I'm technically capable, so, sharing some homemade tools here.
I made these tools with caution to avoid any problem on my device and i'm testing it the best i can. I can make some update sometimes. These tools are not dangerous things and i try to be as clear as possible about what they are done for.
If you decide to use it this is your own decision. I can help if you encounter any trouble but i'm not responsible
. Anyway creating registry keys and copying files are common things your OS do hundred / thousand times per day and i'm not touching sensible things.Windows contextual menu entries (registry keys) :
/!\ this modification will apply to all users on device and not only your user. /!\These are custom Windows contextual menu entries i made to fasten copying files to data / scene. It works with common files used in this folder but not everything (no utility to cover every file extension, to be honest).
So it must work with: .xvm, .afs, .rel, .bml, .prs, .nj, .dat, .gsl, .xj and .bin files.
* You can add or remove files extensions by modifying "AppliesTo" values (see reg code or ask for any question).
How to use:
Right click on the different file types mentioned up there.
/!\ Windows 11: SHIFT + Right-click /!\
How to install:
- Copy/Paste code to a text file, rename extension .reg and then execute file to add keys to your Windows contextual menu.
Version 1.0.1 (added separators before and after)
Code:
Windows Registry Editor Version 5.00
[HKEY_CLASSES_ROOT\*\shell\PSOSendToData]
"Icon"="\"%USERPROFILE%\\EphineaPSO\\psobb.exe\""
"MUIVerb"="PSO: Send to Data"
"AppliesTo"=".xvm OR .afs OR .rel OR .bml OR .prs OR .nj OR .dat OR .gsl OR .xj OR .bin"
"SeparatorBefore"=""
[HKEY_CLASSES_ROOT\*\shell\PSOSendToData\command]
@="cmd.exe /c \"copy \"\"%1\"\" \"\"%%USERPROFILE%%\\EphineaPSO\\data\"\" /V /Y\""
[HKEY_CLASSES_ROOT\*\shell\PSOSendToScene]
"AppliesTo"=".xvm OR .afs OR .rel OR .bml OR .prs OR .nj OR .dat OR .gsl OR .xj OR .bin"
"MUIVerb"="PSO: Send to Scene"
"Icon"="\"%USERPROFILE%\\EphineaPSO\\psobb.exe\""
"SeparatorAfter"=""
[HKEY_CLASSES_ROOT\*\shell\PSOSendToScene\command]
@="cmd.exe /c \"copy \"\"%1\"\" \"\"%%USERPROFILE%%\\EphineaPSO\\data\\scene\"\" /V /Y\""
Code:
Windows Registry Editor Version 5.00
[-HKEY_CLASSES_ROOT\*\shell\PSOSendToData]
[-HKEY_CLASSES_ROOT\*\shell\PSOSendToScene]Installation & backup script :
This batch script help installing & backing up files to/from EphineaPSO folder. Any files if you respect EphineaPSO folder structure inside the folder you add.Create a folder "mods" beside the script and add your fils in subfolder.
Code:
REM Script Author: DeadMeat / B I S C U I T / Discord : biscuitisnotmyname
@echo off
cls
setlocal EnableDelayedExpansion
REM SETTING INSTALLATION FOLDER HERE
set "dest=%USERPROFILE%\EphineaPSO\data"
REM Setting mods folder
set "mods_base=%~dp0mods"
cls
echo .:.:.:.:.:.:.:.:.:.:.:.:.:.:.
echo .: Biscuit's mod installer :.
echo .:.:.:.:.:.:.:.:.:.:.:.:.:.:.
echo.
echo This installer is designed to help with backuping and copying files to "USERNAME\EphineaPSO\data" folder.
echo.
echo Quick instructions:
echo.
echo Files must be added in "mods" folder inside subfolders named like : "name_without_space".
echo Files inside your folder must follow the common structure of "EphineaPSO" folder : "data\scene".
echo.
echo Enjoy and let me know about any advice or improvement :-)
echo.
pause
:MAIN_MENU
for /f "tokens=1-7 delims=/:., " %%a in ("%date% %time%") do (
set "datetime=%%c%%a%%b_%%d%%e%%f"
)
set "datetime=%datetime: =0%"
REM Setting backup folder (default is beside script)
set "current_backup_folder=%~dp0%datetime%_BACKUP"
cls
echo.
echo Current values set in script:
echo.
echo .:. Destination Folder:
echo "%dest%"
echo.
echo IF THE GAME IS NOT INSTALLED IN THE DEFAULT PATH, PLEASE MODIFY THE "DEST" VARIABLE IN THE SCRIPT BEFORE CONTINUE.
echo.
echo .:. Backup folder:
echo "%current_backup_folder%"
echo.
echo .:. Mods main folder (drop any PSO mod INSIDE_A_SUBFOLDER here):
echo "%mods_base%"
echo.
echo -----------------------------------------------------
echo.
if not exist "%dest%" (
echo The folder EphineaPSO does not exist at: %dest%.
echo.
pause
goto :MAIN_MENU
)
if not exist "%mods_base%" (
echo The source files folder %mods_base% does not exist.
echo.
pause
goto :MAIN_MENU
)
echo Subfolders detected in "mods" :
echo ----------------------------------------
set /a count=0
for /d %%d in ("%mods_base%\*") do (
set /a count+=1
echo [!count!] %%~nxd
set "mod_choice[!count!]=%%d"
)
echo ----------------------------------------
echo.
if %count% equ 0 (
echo No mod folders found in "%mods_base%".
echo Ensure your mods are inside subfolders.
echo.
pause
goto :MAIN_MENU
)
:GET_CHOICE
set "user_choice="
set /p "user_choice=Enter the number of the folder to install: "
if not defined user_choice goto GET_CHOICE
if !user_choice! LSS 1 goto GET_CHOICE
if !user_choice! GTR !count! goto GET_CHOICE
set "selected_mod_folder=!mod_choice[%user_choice%]!"
for %%A in ("!selected_mod_folder!") do set "display_folder_name=%%~nxA"
echo.
echo You have chosen to install folder:
echo.
echo "%display_folder_name%"
echo.
echo Press any key to continue or close script to start again
echo.
pause
cls
echo.
echo Step 1: Backing up existing files (if present) to "%current_backup_folder%" ...
if not exist "%current_backup_folder%" (
mkdir "%current_backup_folder%"
)
for /f "delims=" %%f in ('dir /b /s /a-d "%selected_mod_folder%"') do (
set "full_mod_file_path=%%f"
set "relative_file_path=!full_mod_file_path:%selected_mod_folder%\=!"
set "game_dest_file_path=%dest%\!relative_file_path!"
set "backup_target_file_path=%current_backup_folder%\!relative_file_path!"
for %%g in ("!backup_target_file_path!") do set "backup_target_dir=%%~dpg"
if exist "!game_dest_file_path!" (
echo Backing up "!game_dest_file_path!" ...
if not exist "!backup_target_dir!" (
mkdir "!backup_target_dir!"
)
copy /y "!game_dest_file_path!" "!backup_target_file_path!" >nul
) else (
echo NO BACKUP DONE for : "!relative_file_path!". File not found at destination.
)
)
echo Step 1: Backup completed.
echo.
echo Going for "Step 2: Installation"
echo.
pause
echo Step 2: Installing new mod to "%dest%" ...
echo.
xcopy "%selected_mod_folder%" "%dest%" /E /H /Y /K /R
echo.
echo Step 2: Installation of "%display_folder_name%" completed.
echo.
echo Going back to main menu ...
echo.
pause
goto :MAIN_MENU
endlocal
exit /b 0
Last edited: